CXpButton Class

Theme aware push button that can also act as a toggle button and display an icon or bitmap.

• Draws a themed button in Windows XP or superior, using the functions available in UxTheme.dll, or a button with classic appearance in other versions of Windows, using GDI functions.
• Allows up to three images per button (for normal, hot and disabled states). If you want a button with a centered image and no text, use the XPBI_CENTERCENTER flag in the ImagePos method.
• Can be used as a toggle button setting this flag with the Toggle method.
• Images and fonts are owned and destroyed by the control.
• If theming is diabled, you can use you own colors for the different elements of the button: Background, foreground, text, etc.

Constructor

Registers the class name and creates an instance of the control.

CONSTRUCTOR CXpButton (BYVAL pWindow AS CWindow PTR, BYVAL cID AS LONG_PTR, _
   BYREF wszTitle AS WSTRING = "", BYVAL x AS LONG = 0, BYVAL y AS LONG = 0, _
   BYVAL nWidth AS LONG = 0, BYVAL nHeight AS LONG = 0, BYVAL dwStyle AS DWORD = 0, _
   BYVAL dwExStyle AS DWORD = 0, BYVAL lpParam AS LONG_PTR = 0)

Return value

A pointer to the new instance of the class.

Helper Procedure: AfxCXpButtonPtr

Returns a pointer to the CXpButton class given the handle of its associated window.

FUNCTION AfxCXpButtonPtr (BYVAL hwnd AS HWND) AS CXpButton PTR
FUNCTION AfxCXpButtonPtr (BYVAL hParent AS HWND, BYVAL cID AS LONG) AS CXpButton PTR

Return value

A pointer to the CXpButton class.

Methods

Properties

Example

#define UNICODE
#define _WIN32_WINNT &h0602
#INCLUDE ONCE "Afx/CWindow.inc"
#INCLUDE ONCE "Afx/CXpButton.inc"
USING Afx

CONST IDC_BUTTON1 = 1001
CONST IDC_BUTTON2 = 1002
CONST IDC_BUTTON3 = 1003

DECLARE FUNCTION WinMain (BYVAL hInstance AS HINSTANCE, _
                          BYVAL hPrevInstance AS HINSTANCE, _
                          BYVAL szCmdLine AS ZSTRING PTR, _
                          BYVAL nCmdShow AS LONG) AS LONG

   END WinMain(GetModuleHandleW(NULL), NULL, COMMAND(), SW_NORMAL)

' // Forward declaration
DECLARE FUNCTION WndProc (BYVAL hwnd AS HWND, BYVAL uMsg AS UINT, BYVAL wParam AS WPARAM, BYVAL lParam AS LPARAM) AS LRESULT

' ========================================================================================
' Main
' ========================================================================================
FUNCTION WinMain (BYVAL hInstance AS HINSTANCE, _
                  BYVAL hPrevInstance AS HINSTANCE, _
                  BYVAL szCmdLine AS ZSTRING PTR, _
                  BYVAL nCmdShow AS LONG) AS LONG

   ' // Set process DPI aware
   AfxSetProcessDPIAware

   ' // Create the main window
   DIM pWindow AS CWindow
   pWindow.Create(NULL, "XpButton example", @WndProc)
   pWindow.SetClientSize(215, 142)
   pWindow.Center

   ' // Create the first button
   DIM pXpButton1 AS CXpButton = CXpButton(@pWindow, IDC_BUTTON1, "&Hot", 50, 10, 114, 34)
   ' // Load a png icon from file (remember to change tha path of the file)
   pXpButton1.SetImageFromFile(ExePath & "/arrow_left_64.png", XPBI_NORMAL)
   ' // Load a Windows predefined icon as the "hot" image
   pXpButton1.SetIcon LoadIcon(NULL, IDI_QUESTION), XPBI_HOT
   ' // Change the cursor shape
   pXpButton1.SetCursor LoadCursor(NULL, IDC_CROSS)
   ' // Set a margin of 10 dpi units (pixels x scaling ratio)
   pXpButton1.SetImageMargin 10

   ' // Create the second button
   DIM pXpButton2 AS CXpButton = CXpButton(@pWindow, IDC_BUTTON2, "&Cancel", 50, 50, 114, 34)
   ' // Load a Windows predefined icon
   pXpButton2.SetIcon LoadIcon(NULL, IDI_ERROR), XPBI_NORMAL
   pXpButton2.SetImagePos XPBI_RIGHT OR XPBI_VCENTER
   pXpButton2.SetTextFormat DT_LEFT OR DT_VCENTER OR DT_SINGLELINE
'   EnableWindow pXpButton2.hWindow, FALSE   ' Disable the button

   ' // Create a coloured button
   DIM pXpButton3 AS CXpButton = CXpButton(@pWindow, IDC_BUTTON3, "&Coloured Button", 50, 90, 114, 34, WS_VISIBLE OR WS_TABSTOP OR BS_PUSHBUTTON OR BS_CENTER OR BS_VCENTER OR BS_FLAT)
   ' // Disable theming
   pXpButton3.DisableTheming
   ' // Set the background color to blue
   pXpButton3.SetButtonBkColor BGR(0, 0, 255)
   ' // Set the background color when pressed to yellow
   pXpButton3.SetButtonBkColorDown BGR(255, 255, 0)
   ' // Set the text foreground color to yellow
   pXpButton3.SetTextForeColor BGR(255, 255, 0)
   ' // Set the text background color to blue
   pXpButton3.SetTextBkColor BGR(0, 0, 255)
   ' // Set the text foreground color when pressed to white
   pXpButton3.SetTextForeColorDown BGR(255, 255, 255)
   ' // Set the text background color when pressed to red
   pXpButton3.SetTextBkColorDown BGR(255, 0, 0)
   ' // Set the text backround color when pressed to red
   pXpButton3.SetTextBkColorDown BGR(255, 0, 0)
   ' // Set the text format (cnetered and single line)
   pXpButton3.TextFormat = DT_CENTER OR DT_VCENTER OR DT_SINGLELINE
' pXpButton3.SetToggle TRUE   ' make it a toggle button

   ' // Set the focus in the first button
   SetFocus pXpButton1.hWindow

   ' // Dispatch Windows messages
   FUNCTION = pWindow.DoEvents(nCmdShow)

END FUNCTION
' ========================================================================================

' ========================================================================================
' Main window callback procedure
' ========================================================================================
FUNCTION WndProc (BYVAL hwnd AS HWND, BYVAL uMsg AS UINT, BYVAL wParam AS WPARAM, BYVAL lParam AS LPARAM) AS LRESULT

   SELECT CASE uMsg

      CASE WM_COMMAND
         SELECT CASE GET_WM_COMMAND_ID(wParam, lParam)
            CASE IDC_BUTTON1, IDC_BUTTON2, IDC_BUTTON3
               IF GET_WM_COMMAND_CMD(wParam, lParam) = BN_CLICKED THEN
                  ' AfxMsg "Button clicked"
                  EXIT FUNCTION
               END IF

            CASE IDCANCEL
               ' // If ESC key pressed, close the application by sending an WM_CLOSE message
               IF GET_WM_COMMAND_CMD(wParam, lParam) = BN_CLICKED THEN
                  SendMessageW hwnd, WM_CLOSE, 0, 0
                  EXIT FUNCTION
               END IF
         END SELECT

        CASE WM_DESTROY
         ' // Ends the application by sending a WM_QUIT message
         PostQuitMessage(0)
         EXIT FUNCTION

   END SELECT

   ' // Default processing of Windows messages
   FUNCTION = DefWindowProcW(hWnd, uMsg, wParam, lParam)

END FUNCTION
' ========================================================================================

DisableTheming

Disables theming.

SUB DisableTheming

EnableTheming

Enables theming.

SUB EnableTheming

GetImage

Returns the handle of the image.

FUNCTION GetImage (BYVAL ImageState AS LONG) AS HANDLE

Return value

Returns the handle of the requested image.

hWindow

Returns the handle of the button.

FUNCTION hWindow () AS HWND

IsThemed

Returns CTRUE if themes are enabled or FALSE otherwise.

FUNCTION IsThemed () AS LONG

Redraw

Redraws the button.

SUB Redraw

SetBitmap

Sets the bitmap for the button.

SUB SetBitmap (BYVAL hBitmap AS HBITMAP, _
   BYVAL ImageState AS LONG, BYVAL fRedraw AS LONG = FALSE)

SetBitmapFromFile

Loads a bitmap from file and sets it as the image of tbe button.

SUB SetBitmapFromFile (BYVAL pwszPath AS WSTRING PTR, _
   BYVAL ImageState AS LONG, BYVAL fRedraw AS LONG = FALSE)

SetIcon

Sets the icon for the button.

SUB SetIcon (BYVAL hIcon AS HICON, _
   BYVAL ImageState AS LONG, BYVAL fRedraw AS LONG = FALSE)

SetIconFromFile

Loads an icon from file and sets it as the image of tbe button.

SUB SetIconFromFile (BYVAL pwszPath AS WSTRING PTR, _
   BYVAL ImageState AS LONG, BYVAL fRedraw AS LONG = FALSE)

SetImage

Sets the image for the button.

SUB SetImage (BYVAL hImage AS HANDLE, BYVAL ImageType AS LONG, _
   BYVAL ImageState AS LONG, BYVAL fRedraw AS LONG = FALSE)

SetImageFromFile

Loads an image from file and sets it as the image of the button.

SUB SetImageFromFile (BYREF wszPath AS WSTRING, BYVAL ImageState AS LONG, _
   BYVAL dimPercent AS LONG = 0, BYVAL bGrayScale AS LONG = FALSE, _
   BYVAL fRedraw AS LONG = FALSE)

SetImageFromRes

Loads an image from file and sets it as the image of the button.

SUB SetImageFromRes (BYVAL hInstance AS HINSTANCE, BYREF wszImageName AS WSTRING, _
   BYVAL ImageState AS LONG, BYVAL dimPercent AS LONG = 0, _
   BYVAL bGrayScale AS LONG = FALSE, BYVAL fRedraw AS LONG = FALSE)

BkBrush

Returns the background color brush.

PROPERTY BkBrush () AS HBRUSH

ButtonBkColor

Gets/sets the background color of button.

PROPERTY ButtonBkColor () AS COLORREF
PROPERTY ButtonBkColor (BYVAL bkColor AS COLORREF)

Return value

The background color of the button as a COLORREF value.

Remarks

Only available if the button is not themed. Call DisableTheming to disable theming.

ButtonBkColorDown

Gets/sets the background color of button when it is down (pressed or toggled).

PROPERTY ButtonBkColorDown () AS COLORREF
PROPERTY ButtonBkColorDown (BYVAL bkColorDown AS COLORREF)

Return value

The background color of button when it is down (pressed or toggled).

Remarks

Only available if the button is not themed. Call DisableTheming to disable theming.

ButtonBkColorHot

Gets/sets the background color of button when it is hot (the mouse is over it).

PROPERTY ButtonBkColorHot () AS COLORREF
PROPERTY ButtonBkColorHot (BYVAL bkColorHot AS COLORREF)

Return value

The background color of button when it is hot (the mouse is over it).

Remarks

Only available if the button is not themed. Call DisableTheming to disable theming.

ButtonState

Returns the button state.

PROPERTY ButtonState () AS LONG

Return value

The button state: Pushed (BST_PUSHED) or unpushed.

Cursor

Gets/sets the cursor for the button.

PROPERTY Cursor () AS HCURSOR
PROPERTY Cursor (BYVAL hCursor AS HCURSOR)

Return value

The cursor handle.

NormalImageHandle

Returns the handle of the normal image.

PROPERTY NormalImageHandle () AS HANDLE

DisabledImageHandle

Returns the handle of the disabled image.

PROPERTY DisabledImageHandle () AS HANDLE

HotImageHandle

Returns the handle of the hot image.

PROPERTY HotImageHandle () AS HANDLE

Font

Gets/sets the handle of the font used by the button.

PROPERTY Font () AS HFONT
PROPERTY Font (BYVAL hFont AS HFONT)

Return value

The font handle.

ImageHeight

Gets/sets the heigth of the image.

PROPERTY ImageHeight () AS LONG
PROPERTY ImageHeight (BYVAL nHeight AS LONG)

Return value

The height of the image, in pixels.

ImageMargin

Gets/sets the image margin.

PROPERTY ImageMargin () AS LONG
PROPERTY ImageMargin (BYVAL nMargin AS LONG)

Return value

The margin of the image, in pixels.

ImagePos

Gets/sets the image position.

PROPERTY ImagePos () AS LONG
PROPERTY ImagePos (BYVAL nPos AS LONG)

Return value

The position of th image.

ImageType

Returns the image type

PROPERTY ImageType () AS LONG

Return value

The image type: IMAGE_ICON or IMAGE_BITMAP.

ImageWidth

Gets/sets the width of the image.

PROPERTY ImageWidth () AS LONG
PROPERTY ImageWidth (BYVAL nWidth AS LONG)

Return value

The width of the image, in pixels.

TextBkColor

Gets/sets the text background color of the button.

PROPERTY TextBkColor () AS COLORREF
PROPERTY TextBkColor (BYVAL textColor AS COLORREF)

Return value

The text background color of the button as a COLORREF value.

TextBkColorDown

Gets/sets the text background color of the button when it is down (pressed).

PROPERTY TextBkColorDown () AS COLORREF
PROPERTY TextBkColorDown (BYVAL textColor AS COLORREF)

Return value

The text background color of the button when it is down (pressed) as a COLORREF value.

TextForeColor

Gets/sets the text foreground color of the button.

PROPERTY TextForeColor () AS COLORREF
PROPERTY TextForeColor (BYVAL textColor AS COLORREF)

Return value

The text foreground color of the button as a COLORREF value.

TextForeColorDown

Gets/sets the text foreground color of the button when it is down (pressed).

PROPERTY TextForeColorDown () AS COLORREF
PROPERTY TextForeColorDown (BYVAL textColor AS COLORREF)

Return value

The text foreground color of the button when it is down (pressed) as a COLORREF value.

TextFormat

Gets/sets the method of formatting the text.

PROPERTY TextFormat () AS DWORD
PROPERTY TextFormat (BYVAL dwTextFlags AS DWORD)

Default value: DT_CENTER OR DT_VCENTER OR DT_SINGLELINE.

Return value

The method of formatting the text.

TextMargin

Gets/sets the the margin of the text of the button.

PROPERTY TextMargin () AS LONG
PROPERTY TextMargin (BYVAL nMargin AS LONG)

Return value

The text margin.

Toggle

Gets/sets button to toggle state (TRUE) or to pushbutton state (FALSE).

PROPERTY Toggle () AS LONG
PROPERTY Toggle (BYVAL fToggle AS LONG)

Return value

Returns CTRUE if the button is toggled or FALSE otherwise.

ToggleState

Gets/sets the toggle state: pushed (CTRUE) or unpushed (FALSE).

PROPERTY ToggleState () AS LONG
PROPERTY ToggleState (BYVAL fState AS LONG)

Return value

Returns CTRUE if the button is toggled or FALSE otherwise.

Return value

Returns CTRUE if the button is toggled or FALSE otherwise.